mo_read_optional_data.f90

Go to the documentation of this file.

!> \file mo_read_optional_data.f90
!> \brief   \copybrief mo_read_optional_data
!> \details \copydetails mo_read_optional_data
 
!> \brief Read optional data for mHM calibration.
!> \details Data have to be provided in resolution of the hydrology.
!> \authors Matthias Zink
!> \date Mar 2015
!> \copyright Copyright 2005-\today, the mHM Developers, Luis Samaniego, Sabine Attinger: All rights reserved.
!! mHM is released under the LGPLv3+ license \license_note
!> \ingroup f_mhm
MODULE mo_read_optional_data
 
  USE mo_kind, ONLY : i4, dp
 
  IMPLICIT NONE
 
  PRIVATE
 
  PUBLIC :: readoptidataobs
 
  ! ------------------------------------------------------------------
 
CONTAINS
 
  ! ------------------------------------------------------------------
 
  !    NAME
  !        readOptidataObs
 
  !    PURPOSE
  !>       \brief Read evapotranspiration data from NetCDF file for calibration
 
  !>       \details This routine reads oberved evapotranspiration fields which are used for model
  !>       calibration. The evapotranspiration file is expected to be called "et.nc" with
  !>       a variable "et" inside. The data are read only for the evaluation period
  !>       they are intended to be used for calibration. Evapotranspiration data are only
  !>       read if one of the corresponding objective functions is chosen.
 
  !    INTENT(IN)
  !>       \param[in] "integer(i4) :: iDomain" domain Id
 
  !    HISTORY
  !>       \authors Johannes Brenner
 
  !>       \date Feb 2017
 
  ! Modifications:
  ! Robert Schweppe Jun 2018 - refactoring and reformatting
  ! Maren Kaluza Oct 2019 - copied from evapotranspiration and adopted for tws
  ! Maren Kaluza Nov 2019 - removed redundant code, reading works for any gridded optidata
 
  subroutine readoptidataobs(iDomain, domainID, L1_optiObs)
 
    use mo_common_mhm_mrm_variables, only : evalper
    use mo_common_variables, only : level1
    use mo_optimization_types, only: optidata
    use mo_message, only : message
    use mo_read_nc, only : read_nc
    use mo_string_utils, only : num2str
    use mo_timer, only : timer_get, timer_start, &
                         timer_stop
 
    implicit none
 
    ! domain Id
    integer(i4), intent(in) :: idomain
 
    ! domain Id
    integer(i4), intent(in) :: domainid
 
    ! opti data
    type(optidata), intent(inout) :: l1_optiobs
 
    ! loop  vars packing L1_data to L1_data_packed
    integer(i4) :: t
 
    ! level 1 number of culomns and rows
    integer(i4) :: nrows1, ncols1
 
    ! mask of level 1 for packing
    logical, dimension(:, :), allocatable :: mask1
 
    ! ncells1 of level 1
    integer(i4) :: ncells1
 
    ! data at level-1
    real(dp), dimension(:, :, :), allocatable :: l1_data
 
    ! mask at level-1
    logical, dimension(:, :, :), allocatable :: l1_mask
 
    integer(i4) :: ntimesteps_l1_opti      ! [-] number of time steps in L1_opti_mask
 
    ! get basic domain information at level-1
    nrows1 = level1(idomain)%nrows
    ncols1 = level1(idomain)%ncols
    ncells1 = level1(idomain)%ncells
    mask1 = level1(idomain)%mask
 
    !  domain characteristics and read meteo header
    call message('  Reading', trim(l1_optiobs%varname) ,'for domain:           ', trim(adjustl(num2str(domainid))), ' ...')
    call timer_start(1)
    call read_nc(l1_optiobs%dir, nrows1, ncols1, trim(l1_optiobs%varname), mask1, l1_data, &
            target_period = evalper(idomain), nctimestep = l1_optiobs%timeStepInput, nocheck = .true., maskout = l1_mask)
 
    ! pack variables
    ntimesteps_l1_opti = size(l1_data, 3)
    allocate(l1_optiobs%dataObs(ncells1, ntimesteps_l1_opti))
    allocate(l1_optiobs%maskObs(ncells1, ntimesteps_l1_opti))
    do t = 1, ntimesteps_l1_opti
      l1_optiobs%dataObs(:, t) = pack(l1_data(:, :, t), mask = mask1(:, :))
      l1_optiobs%maskObs(:, t) = pack(l1_mask(:, :, t), mask = mask1(:, :))
    end do
 
    !free space
    deallocate(l1_data)
 
    call timer_stop(1)
    call message('    in ', trim(num2str(timer_get(1), '(F9.3)')), ' seconds.')
 
  end subroutine readoptidataobs
 
END MODULE mo_read_optional_data