mo_mhm_messages.F90

Go to the documentation of this file.

!> \file    mo_mhm_messages.f90
!> \brief   \copybrief mo_mhm_messages
!> \details \copydetails mo_mhm_messages
 
!> \brief   Module for mHM messages.
!> \details Write out messages of mHM (startup, checks, status, finish, ect.).
!> \authors Sebastian Mueller
!> \version 0.1
!> \date    Oct 2021
!> \copyright Copyright 2005-\today, the mHM Developers, Luis Samaniego, Sabine Attinger: All rights reserved.
!! mHM is released under the LGPLv3+ license \license_note
!> \ingroup f_mhm
module mo_mhm_messages
 
    use mo_kind, only: i4
    use mo_message, only: message
    use mo_string_utils, only: num2str, separator
 
  implicit none
 
  private
 
  public :: startup_message
  public :: domain_dir_check_message
  public :: finish_message
 
contains
 
  !> \brief write startup message of mHM.
  subroutine startup_message()
    use mo_file, only: &
      version, &
      version_date, &
      file_namelist_mhm, &
      file_namelist_mhm_param, &
      file_defoutput
    use mo_os, only: check_path_isfile, get_cwd
    !$ use omp_lib, only: OMP_GET_NUM_THREADS
 
    implicit none
 
    character(4096) :: message_text
    integer(i4), dimension(8) :: datetime
    logical :: compiled_with_openmp = .false.
    character(len=255)  :: cur_work_dir
    logical :: compiled_with_mpi = .false.
    !$ integer(i4) :: n_threads
 
#ifdef MPI
    compiled_with_mpi = .true.
#endif
 
    ! check for working dir (optional argument to the executable)
    CALL get_cwd(cur_work_dir)
 
    call message(separator)
    call message('              mHM-UFZ')
    call message()
    call message('    MULTISCALE HYDROLOGIC MODEL')
    call message('           Version: ', trim(version))
    call message('           Date:    ', trim(version_date))
    call message()
    call message('Originally by L. Samaniego & R. Kumar')
    call message(separator)
 
    call message()
    !$ compiled_with_openmp = .true.
    if (compiled_with_openmp) then
      call message('OpenMP used.')
    else
      call message('Openmp not used.')
    end if
    !$OMP PARALLEL
    !$ n_threads = OMP_GET_NUM_THREADS()
    !$OMP END PARALLEL
    !$ call message('Run with OpenMP with ', trim(num2str(n_threads)), ' threads.')
 
    call message()
    if (compiled_with_mpi) then
      call message('MPI used.')
    else
      call message('MPI not used.')
    end if
 
    call message()
    call date_and_time(values = datetime)
    message_text = trim(num2str(datetime(3), '(I2.2)')) // "." // trim(num2str(datetime(2), '(I2.2)')) &
      // "." // trim(num2str(datetime(1), '(I4.4)')) // " " // trim(num2str(datetime(5), '(I2.2)')) &
      // ":" // trim(num2str(datetime(6), '(I2.2)')) // ":" // trim(num2str(datetime(7), '(I2.2)'))
    call message('Start at ', trim(message_text), '.')
    call message('Working directory: ', trim(cur_work_dir))
    call message('Using namelists:')
    call message('     ', trim(file_namelist_mhm))
    call message('     ', trim(file_namelist_mhm_param))
    call message('     ', trim(file_defoutput))
    call message()
 
    call check_path_isfile(path = file_namelist_mhm, raise=.true.)
    call check_path_isfile(path = file_namelist_mhm_param, raise=.true.)
    call check_path_isfile(path = file_defoutput, raise=.true.)
 
  end subroutine startup_message
 
  !> \brief Check input directories for mHM.
  subroutine domain_dir_check_message()
    use mo_check, only: check_dir
    use mo_global_variables, only: meteo_handler
    use mo_common_variables, only: &
      dirmorpho, &
      dirlcover, &
      dirout, &
      domainmeta, &
      processmatrix
 
    implicit none
 
    integer(i4) :: domainid, idomain
 
    call message()
    call message('# of domains:         ', trim(num2str(domainmeta%overallNumberOfDomains)))
    call message()
    call message('  Given data directories:')
    do idomain = 1, domainmeta%nDomains
      domainid = domainmeta%indices(idomain)
      call message('  --------------')
      call message('      DOMAIN                  ', num2str(domainid, '(I3)'))
      call message('  --------------')
      call check_dir(dirmorpho(idomain), "Morphological directory:", .false., 4, 30)
      call check_dir(dirlcover(idomain), "Land cover directory:", .false., 4, 30)
      if (.not. meteo_handler%couple_all) &
        call check_dir(meteo_handler%dir_meteo_header(idomain), "Level-2 header directory:", .false., 4, 30)
      if (.not. meteo_handler%couple_pre) &
        call check_dir(meteo_handler%dirPrecipitation(idomain), "Precipitation directory:", .false., 4, 30)
      if (.not. meteo_handler%couple_temp) &
        call check_dir(meteo_handler%dirTemperature(idomain), "Temperature directory:", .false., 4, 30)
      select case (processmatrix(5, 1))
        case(-1 : 0) ! PET is input
          if (.not. meteo_handler%couple_pet) &
            call check_dir(meteo_handler%dirReferenceET(idomain), "PET directory:", .false., 4, 30)
        case(1) ! Hargreaves-Samani
          if (.not. meteo_handler%couple_tmin) &
            call check_dir(meteo_handler%dirMinTemperature(idomain), "Min. temperature directory:", .false., 4, 30)
          if (.not. meteo_handler%couple_tmax) &
            call check_dir(meteo_handler%dirMaxTemperature(idomain), "Max. temperature directory:", .false., 4, 30)
        case(2) ! Priestely-Taylor
          if (.not. meteo_handler%couple_netrad) &
            call check_dir(meteo_handler%dirNetRadiation(idomain), "Net radiation directory:", .false., 4, 30)
        case(3) ! Penman-Monteith
          if (.not. meteo_handler%couple_netrad) &
            call check_dir(meteo_handler%dirNetRadiation(idomain), "Net radiation directory:", .false., 4, 30)
          if (.not. meteo_handler%couple_absvappress) &
            call check_dir(meteo_handler%dirabsVapPressure(idomain), "Abs. vap. press. directory:", .false., 4, 30)
          if (.not. meteo_handler%couple_windspeed) &
            call check_dir(meteo_handler%dirwindspeed(idomain), "Windspeed directory:", .false., 4, 30)
      end select
      call check_dir(dirout(idomain), "Output directory:", .true., 4, 30)
      call message()
    end do
    call message()
 
  end subroutine domain_dir_check_message
 
  !> \brief Finish message for mHM.
  subroutine finish_message()
    use mo_common_variables, only: domainmeta
    use mo_common_mhm_mrm_variables, only: simper, ntstepday
 
    implicit none
 
    integer(i4), dimension(8) :: datetime
    integer(i4) :: ntimesteps
    character(4096) :: message_text
 
    ntimesteps = maxval(simper(1 : domainmeta%nDomains)%julEnd - simper(1 : domainmeta%nDomains)%julStart + 1) * ntstepday
    call date_and_time(values = datetime)
    call message()
    message_text = 'Done ' // trim(num2str(ntimesteps, '(I10)')) // " time steps."
    call message(trim(message_text))
    message_text = trim(num2str(datetime(3), '(I2.2)')) // "." // trim(num2str(datetime(2), '(I2.2)')) &
            // "." // trim(num2str(datetime(1), '(I4.4)')) // " " // trim(num2str(datetime(5), '(I2.2)')) &
            // ":" // trim(num2str(datetime(6), '(I2.2)')) // ":" // trim(num2str(datetime(7), '(I2.2)'))
    call message('Finished at ', trim(message_text), '.')
    call message()
    call message(separator)
    call message('mHM: Finished!')
    call message(separator)
 
  end subroutine finish_message
 
end module mo_mhm_messages